flash.system.ApplicationDomain (Flex™ 2 Language Reference)

Package	flash.system
Class	public final class ApplicationDomain
Inheritance	ApplicationDomain Object

The ApplicationDomain class is a container for discrete groups of class definitions. Application domains are used to partition classes that are in the same security domain. They allow multiple definitions of the same class to exist and allow children to reuse parent definitions.

Application domains are used when an external SWF file is loaded through the Loader class. All ActionScript 3.0 definitions in the loaded SWF file are stored in the application domain, which is specified by the applicationDomain property of the LoaderContext object that you pass as a context parameter of the Loader object's load() or loadBytes() method. The LoaderInfo object also contains an applicationDomain property, which is read-only.

All code in a SWF file is defined to exist in an application domain. The current application domain is where your main application runs. The system domain contains all application domains, including the current domain, which means that it contains all Flash Player classes.

Every application domain, except the system domain, has an associated parent domain. The parent domain of your main application's application domain is the system domain. Loaded classes are defined only when their parent doesn't already define them. You cannot override a loaded class definition with a newer definition.

For usage examples of application domains, see Programming ActionScript 3.0.

The ApplicationDomain() constructor function allows you to create an ApplicationDomain object.

View the examples.

	Property	Defined by
		constructor : Object A reference to the class object or constructor function for a given object instance.	Object
		currentDomain : ApplicationDomain [static][read-only] Gets the current application domain in which your code is executing.	ApplicationDomain
		parentDomain : ApplicationDomain [read-only] Gets the parent domain of this application domain.	ApplicationDomain
		prototype : Object [static] A reference to the prototype object of a class or function object.	Object

	Method	Defined by
		ApplicationDomain(parentDomain:ApplicationDomain = null) Creates a new application domain.	ApplicationDomain
		getDefinition(name:String):Object Gets a public definition from the specified application domain.	ApplicationDomain
		hasDefinition(name:String):Boolean Checks to see if a public definition exists within the specified application domain.	ApplicationDomain
		hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined.	Object
		isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter.	Object
		propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations.	Object
		toString():String Returns the string representation of the specified object.	Object
		valueOf():Object Returns the primitive value of the specified object.	Object

See also

ApplicationDomain class

Constructor detail

ApplicationDomain

()

constructor

public function ApplicationDomain(parentDomain:ApplicationDomain = null)

Creates a new application domain.

Parameters

parentDomain:ApplicationDomain (default = null) — If no parent domain is passed in, this application domain takes the system domain as its parent.

Method detail

getDefinition

()

method

public function getDefinition(name:String):Object

Gets a public definition from the specified application domain. The definition can be that of a class, a namespace, or a function.

Parameters

name:String — The name of the definition.

Returns

Object — The object associated with the definition.

Throws

ReferenceError — No public definition exists with the specified name.

hasDefinition

()

method

public function hasDefinition(name:String):Boolean

Checks to see if a public definition exists within the specified application domain. The definition can be that of a class, a namespace, or a function.

Parameters

name:String — The name of the definition.

Returns

Boolean — A value of true if the specified definition exists; otherwise, false.

Examples

The following example demonstrates runtime class loading.

Notes:

Since the ClassLoader class loads a SWF file, local security needs to be at the file system level.
To run this example, you must have a swf file called RuntimeClasses.swf existing in the same folder as the ApplicationDomainExample.swf file.

Begin by creating the RuntimeClasses.swf file from the following code:

   package {
       import flash.display.Sprite;
       
       public class RuntimeClasses extends Sprite {
           public function RuntimeClasses() {
           }        
       }
   }
   
   import flash.display.Sprite;
   import flash.text.TextField;
   
   class Greeter {
       private var greeting:String;
      
       public function Greeter() {
           greeting = "Hello World";
       }
       
       public function greet():String {
           return greeting;
       }
   }
   
   class VisualGreeter extends Sprite {
       private var greeting:String;
       private var txt:TextField;
            
       public function VisualGreeter() {
           greeting = "Hello World";
           txt = new TextField();
           txt.text = greeting;
           txt.background = true;
           txt.backgroundColor = 0xFF0000;
       }
            
       public function greet():String {
           addChild(txt);
           return txt.text
       }
  }

Then implement the following code:



package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.errors.IllegalOperationError;
    import flash.events.Event;

    public class ApplicationDomainExample extends Sprite {
        private var loader:ClassLoader;
        
        public function ApplicationDomainExample() {
            loader = new ClassLoader();
            loader.addEventListener(ClassLoader.LOAD_ERROR, loadErrorHandler);
            loader.addEventListener(ClassLoader.CLASS_LOADED, classLoadedHandler);
            loader.load("RuntimeClasses.swf");
        }
        
        private function loadErrorHandler(e:Event):void {
            throw new IllegalOperationError("Cannot load the specified file.");
        }
        
        private function classLoadedHandler(e:Event):void {
            var greeterClassRef:Class = loader.getClass("Greeter");
            var greeter:Object = new greeterClassRef();
            trace(greeter.greet()); // Hello World
            
            greeterClassRef = loader.getClass("VisualGreeter");
            greeter = new greeterClassRef();
            addChild(DisplayObject(greeter));
            greeter.greet();
        }
    }
}

import flash.display.Loader;
import flash.errors.IllegalOperationError;
import flash.events.Event;
import flash.events.EventDispatcher;
import flash.events.IOErrorEvent;
import flash.events.SecurityErrorEvent;
import flash.net.URLRequest;
import flash.system.ApplicationDomain;
import flash.system.LoaderContext;

class ClassLoader extends EventDispatcher {
    public static var CLASS_LOADED:String = "classLoaded";
    public static var LOAD_ERROR:String = "loadError";
    private var loader:Loader;
    private var swfLib:String;
    private var request:URLRequest;
    private var loadedClass:Class;
    
    public function ClassLoader() {
        loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
        loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        loader.contentLoaderInfo.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
    }
    
    public function load(lib:String):void {
        swfLib = lib;
        request = new URLRequest(swfLib);
        var context:LoaderContext = new LoaderContext();
        context.applicationDomain = ApplicationDomain.currentDomain;
        loader.load(request, context);
    }
        
    public function getClass(className:String):Class {
        try {
            return loader.contentLoaderInfo.applicationDomain.getDefinition(className) as Class;
        }
        catch(e:Error) {
            throw new IllegalOperationError(className + " definition not found in " + swfLib);
        }
        return null;    
    }
    
    private function completeHandler(e:Event):void {
        dispatchEvent(new Event(ClassLoader.CLASS_LOADED));
    }
    
    private function ioErrorHandler(e:Event):void {
        dispatchEvent(new Event(ClassLoader.LOAD_ERROR));
    }
    
    private function securityErrorHandler(e:Event):void {
        dispatchEvent(new Event(ClassLoader.LOAD_ERROR));
    }
}

Adobe^® Flex™ 2 Language Reference		All Packages \| All Classes \| Language Elements \| Index \| Appendixes \| Conventions \| Frames No Frames
Class ApplicationDomain	Properties \| Methods \| Examples